Скрипт завершения всех сеансов всех видов в одной конкретной базе 1с на сервере 1с

Экспорт в PDF

Дата создания: 2024/07/03 07:17 (C) mihanik

• Сервер 1С
• База 1С
• В базе много разных активных сеансов

Завершить все сеансы всех видов в нужной базе

Выполняется всё несложным скриптом на VBS

Option Explicit
 
Dim ServerName				' имя кластера 1С:Предприятия
ServerName = "server1c"
 
Dim TargetBaseName			' Имя базы от которой отключаем сессии
TargetBaseName = "mybase"
 
Dim ClusterAdmin			' Имя админа кластера, если есть
ClusterAdmin = ""
 
Dim ClusterAdminPassword	' Пароль админа кластера, если есть.
ClusterAdminPassword = ""
 
Dim Connector
Dim AgentConnection
Dim Cluster
Dim Clusters
Dim WorkingProcesses
Dim IBB
Dim IBBl
Dim Sessions
Dim SessionsActiv
Dim MyBaseName
 
Set Connector = CreateObject("V83.COMConnector")
	Set AgentConnection = Connector.ConnectAgent(ServerName)
		Clusters = AgentConnection.GetClusters()
 
		For Each Cluster In Clusters
			AgentConnection.Authenticate Cluster, ClusterAdmin,ClusterAdminPassword
			WorkingProcesses = AgentConnection.GetWorkingProcesses(Cluster)
			IBB = AgentConnection.GetInfoBases(Cluster)
				For Each IBBl In IBB
					Sessions = AgentConnection.GetInfoBaseSessions (Cluster,IBBl)
					For Each SessionsActiv In Sessions
						If (SessionsActiv.AppID <> "COMConsole") Then 
							MyBaseName = IBBl.Name
							if TargetBaseName = MyBaseName Then
								wscript.Echo "Отключаем: " & SessionsActiv.userName & " от " & MyBaseName
								AgentConnection.TerminateSession Cluster,SessionsActiv
							End If
						End if
					Next
				Next
		Next
	Set AgentConnection = nothing
Set Connector = nothing

Файл со скриптом: kickout1cusersfrommybase.vbs

• https://its.1c.ru/
• https://www.vbsedit.com/

⇑ Наверх ⇑